Comment remplacer un texte dans une cellule avec la fonction REMPLACER d’Excel ?

Aujourd’hui, je vais vous montrer comment modifier un texte contenu dans une cellule en utilisant la fonction REMPLACER d’Excel. Nous verrons également quelles sont les différences avec une autre fonction d’Excel qui permet elle aussi de remplacer des textes : la fonction SUBSTITUE().

Téléchargement

Vous pouvez télécharger le fichier d'exemple de cet article en cliquant sur le lien suivant :

Tutoriel Vidéo

1. Présentation

Lorsque nous utilisons Excel, il peut arriver régulièrement que nous ayons besoin de modifier un texte contenu dans une cellule par un autre.

Pour cela, nous avons déjà eu l’occasion de découvrir la fonction SUBSTITUE().

Cette fonction permet d’analyser une chaîne de caractère afin de remplacer un texte donné par un autre :

=SUBSTITUE(A6;"bleue";"verte") 

Dans cet exemple, nous remplaçons le mot « bleue » qui se trouvent dans la cellule A6 par le mot « verte » :

Maintenant, nous allons découvrir une autre fonction, qui permet également d’effectuer des remplacements dans une chaîne de caractères, mais qui fonctionne d’une manière totalement différente.

Il s’agit de la fonction REMPLACER().

2. La fonction REMPLACER()

La fonction REMPLACER() permet en effet de remplacer les caractères d’un texte en fonction de leur position.

Cette fonction attend quatre arguments :

• Ancien_texte : il s’agit du texte à analyser, dans lequel nous souhaitons modifier une partie du contenu,
• No_depart : il s’agit de la position du premier caractère que nous souhaitons remplacer, au sein du texte principal ancien_texte,
• No_car : il s’agit du nombre de caractères à extraire de la chaîne principale ancien_texte avant de les remplacer,
• Nouveau_texte : il s’agit du texte à insérer à la place du sous-texte défini

=REMPLACER(A8;12;6;"verte")

Ici nous partons toujours du même texte (« Une orange bleue ») nous souhaitons modifier la couleur « bleue » par « verte ».

Le nombre de caractères à remplacer ne doit pas forcément correspondre au nombre de caractères à insérer :

Nous pouvons ainsi insérer plus de caractères :

=REMPLACER(A8;12;6;"verte et rouge") 

Ou moins de caractères :

=REMPLACER(A8;12;6;"mûre")

Ou même utiliser une chaîne de caractères vide, ce qui permet de supprimer une partie des caractères contenus dans une chaîne principale, en fonction des paramètres défini lors de l’appel de la fonction :

=REMPLACER(A8;12;6;"")

3. Remplacement dynamique

Pour définir la position des caractères à remplacer de manière dynamique, nous pouvons encapsuler dans la fonction REMPLACER() la sous-fonction TROUVE().

La fonction TROUVE() va en effet nous permettre d’obtenir la position à partir de laquelle nous souhaitons effectuer le remplacement.

Par exemple, pour identifier la position de l’espace dans la cellule A10, nous utiliserons la fonction :

 =TROUVE(" ";A10)

Pour connaître la position de la première lettre du mot suivant, nous ajoutons alors +1 :

 =TROUVE(" ";A10)+1

Puis,  pour déterminer la position de l’espace suivant, nous utilisons la même fonction, en faisant démarrer la recherche à partir du résultat obtenu précédemment :

 =TROUVE(" ";A10;TROUVE(" ";A10)+1)

À partir de là, nous pouvons déterminer le nombre de caractères à remplacer par simple différence :

= TROUVE(" ";A10;TROUVE(" ";A10)+1)-(TROUVE(" ";A10)+1)

Et donc la formule finale qui permettrait de modifier le deuxième mot de la chaîne est alors :

=REMPLACER(A10;TROUVE(" ";A10)+1;TROUVE(" ";A10;TROUVE(" ";A10)+1)-(TROUVE(" ";A10)+1);"fraise")

Bien entendu, pour exemple en particulier cette fonction n’a que peu d’intérêt, étant donné que nous pourrions tout aussi bien utiliser la fonction SUBSTITUE() , ce qui serait bien sûr beaucoup plus simple :

=SUBSTITUE(A10;"orange";"fraise") 

4. La fonction REMPLACERB()

La fonction REMPLACER() que nous venons de découvrir permet donc de remplacer les caractères contenus dans une chaîne en fonction de la position.

Sachez qu’il existe une déclinaison de cette fonction : il s’agit de la fonction REMPLACERB().

Cette dernière permet de définir la taille occupée par chaque caractère, ce qui sera utile pour manipuler des polices de caractères qui ne pourront pas être encodées sur un seul octet, telles que les polices japonaise, chinoises ou encore coréenne.

Cette fonction introduit un cinquième argument qui est no_octet et qui trouve sa place en quatrième position :

5. REMPLACER() ou SUBSTITUE() ?

Pour conclure, quand faut-il utiliser l’une ou l’autre de ces fonctions ?

En effet, comme nous l’avons vu dans les parties précédentes, les fonctions REMPLACER() et SUBSTITUE() permettent toutes les deux d’effectuer un remplacement dans un texte.

En revanche, celles-ci sont totalement différentes dans leur fonctionnement et leur résultat.

La fonction SUBSTITUE(), permet en effet de remplacer une chaîne dans un morceau de texte.

La fonction REMPLACER() quant à elle permet de définir quelle partie du texte doit être remplacée.

Contrairement à la fonction SUBSTITUE() qui permet au choix de remplacer soient toutes les occurrences, soit seulement une occurrence donnée, la fonction REMPLACER() ne permet que d’effectuer un seul remplacement, à la position et la taille donnée.

De plus la fonction SUBSTITUE() est bien plus simple à utiliser, il suffit de connaître le mot à remplacer ainsi que le mot de remplacement, là où la fonction REMPLACER() demande de connaître la position des caractères à modifier, que ce soit par un dénombrement manuel, ou par utilisation de la fonction TROUVE().